ARBRE2D: UN PROGRAMME GÉNÉRANT DES ARBRES

Commentaire de BruNews le 15/01/2008 23:58:26 administrateur CS

ndubien, je sens que vais être désagréable (non non je plaisante, quoi que...).
COLORREF temp = GetPixel( hdc, x, y );
if(GetRValue(temp) == 255 && GetGValue(temp) == 255 && GetBValue(temp) == 255) SetPixel(hdc, x, y, RGB(0,0,0));
Une aussi énorme horreur dans la boucle critique, NONNNNNNN !!!
Va donc voir l'ASM du compilo, tu seras dégouté.
if((tmp & 0xFFFFFF) == 0xFFFFFF) tmp = 0;
else tmp = ... je te le laisse celui ci
SetPixel(hdc, x, y, tmp);

Maintenat juste pour le fun, teste ceci qui booste sérieusement le dessin.
J'ai commenté autant que j'ai pu.
__declspec(naked) void __stdcall TracerTraitVert(HDC hdc, double Ax, double Ay, double Bx, double By)
{
  __asm {
    push      ebx
    push      ebp
    push      esi
    push      edi
    ;// hdc [esp+20], Ax [esp+24], Ay [esp+32], Bx [esp+40], By [esp+48]
    cvttsd2si eax, [esp+24]   ;// x1 = round(Ax)
    cvttsd2si ecx, [esp+32]   ;// y1 = round(Ay)
    cvttsd2si ebx, [esp+40]   ;// EBX = x2 = round(Bx)
    cvttsd2si esi, [esp+48]   ;// ESI = y2 = round(By)
    push      eax
    push      ecx
    mov       edi, eax
    cvtsi2sd  xmm3, ebx       ;// xmm3 = x2
    cvtsi2sd  xmm4, esi       ;// xmm4 = y2
    mov       eax, ebx
    sub       eax, edi        ;// x2 - x1
    cdq
    mov       edi, eax
    xor       edi, edx
    mov       eax, esi
    sub       edi, edx        ;// EDI = nbBoucles = abs(x2-x1)
    sub       eax, ecx        ;// y2 - y1
    cdq
    xor       eax, edx
    sub       eax, edx        ;// eax = abs(y2-y1)
    push      0               ;// x1*i
    push      0               ;// y1*i
    cmp       edi, eax
    jae       short bclOK
    mov       edi, eax        ;// EDI = nbBoucles
bclOK: ;// EDI = nbBoucles, EBX = x2, ESI = y2
    ;// hdc = [esp+36], x1 = [esp+12], y1 = [esp+8], x1*i = [esp+4], y1*i = [esp]
    xor       ebp, ebp        ;// EBP = i
    test      edi, edi
    je        short tracerEXIT
    cvtsi2sd  xmm5, edi
forITOBCL: ;// xmm3 = dbl(x2), xmm4 = dbl(y2), xmm5 = dbl(nbBoucles)
    cvtsi2sd  xmm6, ebp     ;// i
    movsd     xmm7, xmm5
    cvtsi2sd  xmm0, [esp+4] ;// xmm0 = x1*i
    subsd     xmm7, xmm6    ;// xmm7 = nbBoucles - i
    cvtsi2sd  xmm1, [esp]   ;// xmm1 = y1*i
    movsd     xmm2, xmm7    ;// xmm2 = nbBoucles - i
    divsd     xmm0, xmm5    ;// (x1*i) / nbBoucles
    mulsd     xmm7, xmm3    ;// xmm7 = x2 * (nbBoucles - i)
    mulsd     xmm2, xmm4    ;// xmm2 = y2 * (nbBoucles - i)
    divsd     xmm7, xmm5
    divsd     xmm2, xmm5
    divsd     xmm1, xmm5    ;// (y1*i) / nbBoucles
    addsd     xmm0, xmm7    ;// x
    addsd     xmm1, xmm2    ;// y
    mov       eax, [esp+36] ;// EAX = hdc
    cvttsd2si ebx, xmm1     ;// EBX = y
    cvttsd2si esi, xmm0     ;// ESI = x
    push      0             ;// deja dispo pour SetPixel(hdc, x, y, 0)
    push      ebx
    push      esi
    push      eax           ;// params SetPixel OK
    push      ebx
    push      esi
    push      eax
    call      dword ptr GetPixel
    mov       edx, eax      ;// EAX = EDX = temp
    and       eax, 0FFFFFFh
    add       dh, 1         ;// GetGValue(temp)+1
    cmp       eax, 0FFFFFFh
    je        short goSETPIX
    mov       [esp+12], edx
goSETPIX:
    call      dword ptr SetPixel
    inc       ebp
    mov       eax, [esp+12] ;// x1
    cmp       ebp, edi
    jg        short tracerEXIT
    mov       edx, [esp+8]  ;// y1
    add       [esp+4], eax  ;// x1*i
    add       [esp], edx    ;// y1*i
    jmp       short forITOBCL
tracerEXIT:
    add       esp, 16
    xor       eax, eax  ;// dummy
    pop       edi
    pop       esi
    pop       ebp
    pop       ebx
    ret       36
  }
}

Commentaire de Renfield le 16/01/2008 10:14:34 administrateur CS

voire peut etre même passer par la manipulation des bits d'un DIB directement...
pas de SetPixel en boucle, quoi... (GetDibBits / SetDibBits)

SetPixelV serait même une petite amélioration interessante (pas de retour de l'ancienne valeur)

Commentaire de ndubien le 16/01/2008 16:19:31

Bonjour Brunews,
merci pour le code de TracerTraitVert en ASM...
Sinon, pour l'utilisation des fonctions dans WM_PAINT, il est vrai que ce n'est pas conseillé pour ce genre de fonction qui peut prendre du temps mais c'était juste pour tester les fonctions et en voir le résultat.
Que me conseillez-vous de moins lourd?
Merci d'avance et à bientôt...

Commentaire de ndubien le 16/01/2008 17:46:48

Bonjour RenField,
Lorsque vous dites "stockes la dans un hBMP tampon"...
hBMP veut-il bien dire HBITMAP?
si oui, celà signifie que je dois stocker mon "image" crée sur un HDC dans HBITMAP...
comment faut-il que je procède?
Merci d'avance...